リスト2　getevmon.bat（Windows）

@echo off
REM  create an event monitor and capture its output
REM  parameters: (1) database name
REM              (2) monitor output file
REM              (3) interval to monitor for (seconds)
REM  Note: You may receive an error about the monitor heap being too small. You may want to set 
REM        mon_heap_sz to 2048 while monitoring.

:CHECKINPUT
IF ""=="%3" GOTO INPUTERROR
GOTO STARTPRG

:INPUTERROR
echo %0 requires 3 parameters: dbname filename sleep_interval
echo e.g. "%0 sample evmon0302.out 60"
GOTO END

:STARTPRG
SET dbname=%1
SET outfile=%2
SET sleep_interval=%3

SET MON=evmon
REM "nonblocked" may cause loss of data but has less impact on system than default "blocked".
SET MONTYPE=nonblocked
REM SET EVENTS="deadlocks with details"
REM SET EVENTS="tables, statements, deadlocks with details, connections"
SET EVENTS="statements"
SET OUTDIR="c:\temp\evmon"

mkdir %OUTDIR%
db2 connect to %dbname%

db2 -v drop event monitor %MON%
db2 -v create event monitor %MON% for %EVENTS% write to file '%OUTDIR%' buffersize 64 %MONTYPE%

db2 -v set event monitor %MON% state = 1
echo Sleeping for %sleep_interval% seconds before turning off.
sleep %sleep_interval%
db2 -v set event monitor %MON% state = 0

db2evmon -db %dbname% -evm %MON% > %OUTFILE%

db2 -v drop event monitor %MON%
db2 terminate
rmdir /s /q %OUTDIR%
echo db2evmon output is in %OUTFILE%

:END